;	TTYLPP - SET lines/page in TTY terminal driver 
;
;       Copyright [c] Noel Alaska Systems Technology, 1983.
 
VMAJOR	=	1.			; version equates
VMINOR	=	0.
VSUB	=	0.
VEDIT	=	0.			; CHANGE EACH EDIT <-----------
VWHO	=	0.
 
        SEARCH  SYS                     ; AMOS librarys
        SEARCH  SYSSYM
	SEARCH	TRM
	SEARCH	MFN			; My library
 
        DSECT
        .=0				; define impure area
TERM:	BLKW	2 
BUFF:	BLKB	8. 
        EVEN
IMPURE  =       .
        .=0
        PSECT

BEGIN:  PHDR    -1,-1,PH$REE!PH$REU
        GETIMP  IMPURE,A4               ; get memory

	LIN 
	BNE	0$ 
	TYPECR	<?terminal not specified.> 
	EXIT 

0$:	FILNAM	TERM(A4),XXX	; get terminal name 
	PUSH	A2 
	MOV	TRMDFC,A5	; point to TRMDEF chain 

1$:	CMM	TERM(A4),4(A5)	; is this the right one? 
	BEQ	3$		;   YES 
	MOV	@A5,A5		; advance TRMDEF pointer 
	MOV	A5,D7
	BNE	1$		; loop thru them all... 
	TYPECR	<?terminal not found.> 
	EXIT 

3$:	ADD	#10,A5		; point to STS (base) 
	LEA	A1,TERM(A4)	; print terminal name 
	CALL	PRINT 
	POP	A2 
	MOV	T.TDV(A5),A3	; check for TTY.TDV 
	SUB	#4,A3		; point to name 
	TST	SYSBAS		;  allow to be in sysmem 
	BEQ	4$		;  instead of TDV chain 
	CMP	A3,SYSBAS 
	BLO	4$ 
	SUB	#2,A3 
4$:	CMMW	#[TTY],@A3 
	BNE	5$ 
	CMMW	#[   ],2(A3) 
	BEQ	6$ 
5$:	TYPECR	< is not using TTY.TDV!> 
	EXIT 

6$:	BYP 
	LIN 
	BNE	7$ 
	TYPE	< is set at > 
	MOV	T.IMP(A5),A5 
	CLR	D1
	MOVB	1(A5),D1
	DCVT	0,2 
	TYPECR	< lines per page.> 
	EXIT 

7$:	CMMB	#54,@A2 		; comma
	BNE	8$ 
	INC	A2 
	BR	6$ 
8$:	GTDEC 
	BMI	9$ 
	MOV	T.IMP(A5),A5 
	MOVB	D1,1(A5)
	CLRB	2(A5)
	TYPE	< is now set at > 
	DCVT	0,2 
	TYPECR	< lines per page.> 
	EXIT 

9$:	TYPECR	< ?? invalid LPP ??> 
	EXIT 
 
; routine to print RAD50 name pointed to by A1 
PRINT:	LEA	A2,BUFF(A4)	; point to buffer 
	UNPACK			; ascii into buffer 
	UNPACK 
0$:	CMPB	-(A2),#40	; remove trailing spaces 
	BEQ	0$ 
	CLRB	1(A2)		; mark end 
	TTYL	BUFF(A4)	; print buffer 
	RTN 

	EVEN
	END